En Toutes Lettres 2

.. la suite !!
Rubrique Moi

Pour celles et ceux qui se sont creusés (cf Margouillat), je vous offre une version toute nouvelle (de ce soir, en fait) de la Routine de Décryptage de l'Image représentant la Police de Caractères ms-dos.

Tout d'abord, récupérez cette image dans l'article précédent, et enregistrez-la sur votre machine, au format BMP monochrome. Le Fichier obtenu doit avoir une Taille de 2750 Octets.

1) Explication de la Structure du Fichier Image Monochrome

Chaque Pixel ne peut avoir que deux valeurs (allumé ou éteint), ce qui se code sur un seul Bit. Un Octet, 8 bits, peut donc représenter 8 Pixels consécutifs. Notre Police se compose de caractères de 8 Pixels de large sur 12 Pixels de haut. Chaque Caractère est donc codé sur 12 Octets, mais pas consécutifs..

Nous avons "zappé" les 32 premiers Caractères de la Police, il en reste donc 224. La Taille Totale représente 224x12=2688 Octets. Les 62 Octets restants sont l'En-Tête du Fichier, dans lequel sont codées des informations comme le format, la largeur et la hauteur de l'image, le nombre de couleurs (ici 2), etc.. Nous ne l'exploiterons pas ici.

Je vous avais dit que le Fichier commence par la Ligne du Bas, par conséquent les premiers Caractères de notre Police sont en Fin de Fichier :-) Une Ligne de notre Police contient 16 Caractères. Le Premier Octet (ligne du haut) du Premier Caractère (l'espace), se trouve donc en position 2750-16+1=2735. L'Octet suivant (2736) correspond à la Ligne du Haut du Second Caractère (le "!"), etc.. La Seconde Ligne du Premier Caractère (l'espace) se situe .. 16 Octets en Amont, soit en 2735-16
=2719ème Position, etc..

Tout le monde suit ? Alors que contient l'Octet n° 63, le premier de l'image juste après l'en-tête (vous avez 30 secondes ;-D)

- Il contient la Ligne du Bas du Caractère en Bas à Gauche de l'image (une barre horizontale) !! Bravo si vous avez trouvé !!

2) Le Code en Cadeau

Le code ci-dessous est écrit pour tourner en VBA6, sous Excel versions 2000 ou plus. Si vous n'avez pas Excel, vous pouvez l'utiliser sous Word, ou même Powerpoint, etc.. moyennant de changer les deux lignes de récupération du répertoire..

Mode d'emploi: Lancer Excel, avec un Classeur Vide. Appeler l'Editeur VBA (menu Outils->Macros->Editeur VBA, ou Alt-F11 au clavier)
Copier le code ci-dessous, et le coller dans l'éditeur VBA. Enregistrer le classeur dans le même répertoire que l'image.

' ----------------------------
' TabConv (P)2006-2008 MyLzz59
' ( code vba6 - excel 2000&+ )
' ----------------------------
Sub TabConv()
' Chemin et Nom de l'Image
Fic$ = ThisWorkbook.Path
If Right$(Fic$, 1) <> "\" Then Fic$ = Fic$ + "\"
Fic$ = Fic$ + "FIC.BMP" ' Mettre le Nom du Fichier ici..
' Vérifications Sommaires (l'Image Monochrome comporte 2750 Octets)
If Dir$(Fic$) = "" Then MsgBox "BMP Pas Trouvé", vbCritical: Exit Sub
If FileLen(Fic$) <> 2750 Then MsgBox "BMP non conforme", vbCritical: Exit Sub
' Ouverture Image
Open Fic$ For Random As #1 Len = 1
Dim Buf As String * 1
' Ouverture Fichier de Sortie
Open Fic$ + ".Log" For Output As #2
Print #2, "(P)2006-2008 MyLzz59"
For Caractere = 32 To 255' Cf mon Explication ;-)
' (X,Y) Matrice Image
PosY = Caractere \ 16: PosX = Caractere Mod 16
' Position dans le Fichier
PosF = 2735 - 16 * 12 * (PosY - 2) + PosX
' Ecriture En-Tête du Caractère
Print #2, "Caractère n°" + Str(Caractere) + " :"
' Initialisation Compteur
NbPixels = 0
' Lecture
For DeltaY = 0 To 11 ' 12 Pixels de Haut
Get #1, PosF - 16 * DeltaY, Buf: Octet = Asc(Buf)
Chaine$ = " "
' Transformation et Comptage
For DeltaX = 0 To 7 ' 8 Pixels de Large
EtatPixel = (Octet And (2 ^ (7 - DeltaX))) <> 0
Chaine$ = Chaine$ + IIf(EtatPixel, "#", ".")
NbPixels = NbPixels - EtatPixel
Next DeltaX
' Ecriture Image ligne
Print #2, Chaine$
Next DeltaY
' Ecriture Conclusion
Print #2, "Allumés=" + Str$(NbPixels) + " (";
Print #2, Format$(NbPixels / 96 * 100, "##0.00") + "%)"
Print #2, ""
Next Caractere
' Fermeture Fichiers
Print #2, "": Close #1: Close #2
' Afficher Fichier de Sortie
Call Shell("notepad.exe """ + Fic$ + ".Log""", vbNormalFocus)
End Sub

C'est fait ? Bon, pour Word, remplacer "Fic$ = ThisWorkbook.Path" par "Fic$ = ThisDocument.Path", etc..

Tout va bien ? Alors placez le curseur n'importe où mais dans ce code (entre SUB et END SUB) et écrasez (gentiment) la touche "F5" du clavier. Si vous avez respecté les consignes, le bloc-notes devrait s'ouvrir et afficher le fichier résultat...

Enjoy !!

-MyLzz59-